home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / COILTAP.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-01-28  |  2.5 KB  |  97 lines
  1. 10  'COILTAP - Tapped Coils - 26 MAY 95 rev. 27 SEP 96
  2. 20  IF EX$=""THEN EX$="EXIT"
  3. 30  CLS:KEY OFF
  4. 40  COLOR 7,0,1
  5. 50  UL$=STRING$(80,205)
  6. 60  U$="####.###"
  7. 70  U1$="###.#"
  8. 80  U2$="###.##"
  9. 90  E$=STRING$(80,32)
  10. 100  PI=3.14159
  11. 110  '
  12. 120  '.....start
  13. 130  CLS
  14. 140  COLOR 15,2
  15. 150  PRINT " COIL TAP CALCULATOR";TAB(57);"by George Murphy VE3ERP ";
  16. 160  COLOR 1,0:PRINT STRING$(80,223);
  17. 170  COLOR 7,0
  18. 180  Z=7
  19. 190  PRINT TAB(Z);
  20. 200  PRINT "This program calculates locations of taps for specific inductances"
  21. 210  PRINT TAB(Z);
  22. 220  PRINT "on any close-wound single-layer air-core coil."
  23. 230  PRINT UL$;
  24. 240  PRINT " Press number in < > to choose standard units of measure:"
  25. 250  PRINT UL$;
  26. 260  PRINT "   < 1 >  Metric"
  27. 270  PRINT "   < 2 >  U.S.A./Imperial"
  28. 280  PRINT UL$;
  29. 290  PRINT "     or Press < 0 > to exit....."
  30. 300  Z$=INKEY$:IF Z$=""THEN 300
  31. 310  IF Z$="0"THEN CLS:RUN EX$
  32. 320  IF Z$="1"THEN UM=25.4:UM$="mm.":GOTO 350
  33. 330  IF Z$="2"THEN UM=1:UM$="in.":GOTO 350
  34. 340  GOTO 300
  35. 350  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  36. 360  GOTO 430
  37. 370  '
  38. 380  '.....format input line
  39. 390  USIN$="####.###":LOCATE CSRLIN-1:PRINT SPC(7);
  40. 400  LOCATE CSRLIN,47:PRINT STRING$(7,".");USING U$;Z;
  41. 410  RETURN
  42. 420  '
  43. 430  '.....initial inputs
  44. 440  PRINT " ENTER: Coil Diameter............................(";UM$;")";:INPUT D
  45. 450  IF D=0 THEN LOCATE CSRLIN-1:PRINT E$;:LOCATE CSRLIN-1:GOTO 440
  46. 460  Z=D:GOSUB 380:PRINT " ";UM$:D=D/UM
  47. 470  INPUT " ENTER: Number of turns..............................";T
  48. 480  IF T=0 THEN LOCATE CSRLIN-1:PRINT E$;:LOCATE CSRLIN-1:GOTO 470
  49. 490  Z=T:GOSUB 380
  50. 500  PRINT " ENTER: Length of coil...........................(";UM$;")";:INPUT LG
  51. 510  IF LG=0 THEN LOCATE CSRLIN-1:PRINT E$;:LOCATE CSRLIN-1:GOTO 500
  52. 520  Z=LG:GOSUB 380:PRINT " ";UM$:LG=LG/UM
  53. 530  UH=(D^2*T^2)/(18*D+40*LG)
  54. 540  PRINT "        Inductance of whole coil.....................";USING U$;UH;
  55. 550  PRINT " >H"
  56. 560  SP=LG/T:S=SP*UM   'turn spacing
  57. 570  PRINT "        Turns spacing (c.c.).........................";USING U$;S;
  58. 580  PRINT " ";UM$
  59. 590  PRINT UL$;
  60. 600  '
  61. 610  INPUT " ENTER: Number of taps required......................";Q
  62. 620  LOCATE CSRLIN-1:PRINT E$;:LOCATE CSRLIN-1
  63. 630  DIM T(Q),U(Q)
  64. 640  FOR Z=1 TO Q
  65. 650  PRINT " ENTER: INDUCTANCE (>H) at tap no.";Z;:INPUT U
  66. 660  IF U>=UH THEN BEEP:GOTO 650
  67. 670  U(Z)=U
  68. 680  NEXT Z
  69. 690  VIEW PRINT 9 TO 24:CLS:VIEW PRINT:LOCATE 9
  70. 700  FOR Z=1 TO Q
  71. 710  U=U(Z)
  72. 720  L=0.1        'initial distance to tap
  73. 730  NT=L/SP     'number of turns
  74. 740  UZ=(D^2*NT^2)/(18+D+40*L)
  75. 750  IF UZ<U THEN L=L+0.01:GOTO 730
  76. 760  PRINT TAB(9);USING U1$;U;:PRINT " >H tap is";USING U1$;NT;
  77. 770  PRINT " turns (";USING U2$;L*UM;
  78. 780  PRINT " ";UM$;") from input end of coil"
  79. 790  NEXT Z
  80. 800  GOSUB 840
  81. 810  ERASE T,U
  82. 820  GOTO 120    'start
  83. 830  '
  84. 840  'HARDCOPY
  85. 850  GOSUB 960:LOCATE 25,2:COLOR 14,6
  86. 860  PRINT " Press 1 to print screen, 2 to print screen & ";
  87. 870  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  88. 880  Z$=INKEY$:IF Z$="3"THEN GOSUB 960:RETURN
  89. 890  IF Z$="1"OR Z$="2"THEN GOSUB 960:GOTO 910
  90. 900  GOTO 880
  91. 910  FOR QX=1 TO 24:FOR QY=1 TO 80
  92. 920  LPRINT CHR$(SCREEN(QX,QY));
  93. 930  NEXT QY:NEXT QX
  94. 940  IF Z$="2"THEN LPRINT CHR$(12)
  95. 950  GOTO 850
  96. 960  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  97.